class Florets
{
  int seedNum; // Number of seeds in the entire spiral
  Floret[] florets; // array holding all the original florets that compose the spiral
  float seedSize = 20; // diameter of seeds

  Florets(int sn)
  {
    seedNum = sn;
    florets = new Floret[seedNum];
  }

// create florets, links, and draw them out
  void init()
  {
    generateFlorets();
    generateNetwork();
    drawFlorets();
  }
  
  // fill array with florets positioned according to Fermat's spiral
  void generateFlorets()
  {
    for(int i=0; i<seedNum; i++)
    {
      float x, y, r, theta; // values for x and y location of ellipse to be drawn and length of hypotenuse
      /*  THETA: polar angel 
       *    The counterclockwise angle from the x-axis at which a point in the 
       *    xy-plane lies.)  the radian value (137.5 degrees) is the value of 
       *    angualr deflection that Mathai and Davis write about a constant in 
       *    Fermat's spiral
       */
      theta = i*2.3999498; 
      r =  seedSize*0.5*pow(theta, .5); // the distance of the floret from the origin
      x = sin(theta)*r + width/2; 
      y = cos(theta)*r + height/2;
      noStroke();
      fill(225);
      Floret newFloret = new Floret(x,y,seedSize); // create floret at calculated location
      florets[i] = newFloret; // store new floret in array
    }
  }

  // draws line of connections between florets
  void generateNetwork()
  {
    //fill(0, 102, 153);
    noFill();
    stroke(0, 102, 153);
    for(int i=0; i<13; i++ )
    {
      // clockwise spiral
      int j = i;
      beginShape();
      curveVertex( florets[j].x, florets[j].y );
      while(j < numFlorets)
      {
        curveVertex( florets[j].x, florets[j].y );
        j += 13;
      }
      curveVertex( florets[j-13].x, florets[j-13].y );
      endShape();
    }
    for(int i=0; i<21; i++ )
    {
      // counter clockwise spiral
      int j = i;
      beginShape();
      curveVertex( florets[j].x, florets[j].y );
      while(j < numFlorets)
      {
        curveVertex( florets[j].x, florets[j].y );
        j += 21;
      }
      curveVertex( florets[j-21].x, florets[j-21].y );
      endShape();
    }
  }
  // return florets to their original white color
  void clearFlorets()
  {  
    for(int i=1; i<seedNum; i++)  {  
      florets[i].reset();  
    }  
  }
  // draw all the florets in the array on the screen with their numbers
  void drawFlorets()
  {  
    PFont font;
    font = loadFont("DecoTypeNaskh-8.vlw");
    textFont(font);
    for(int i=1; i<seedNum; i++)  
    {  
      florets[i].drawFloret();  
      fill(0, 102, 153);
      text(i, florets[i].x, florets[i].y); // print number in array on floret
    }  
  }
  // checks if mouse is over floret and changes settings
  void checkSetClicked()
  {
    for(int i=1; i<numFlorets; i++)
    {
      // if the mosue is over the floret
      if(florets[i].isThere(mouseX, mouseY))
      {
        int a,b; // variables for the fib value that locates adjacet pieces
        a = 21; 
        b = 13;

        clearFlorets();
        // set the floret to blue
        florets[i].setClicked();
        // and the adjecent florets to light blue
        if(i-a >= 1) florets[i-a].setNear();  
        if(i-b >= 1) florets[i-b].setNear();  
        if(i+b <= numFlorets) florets[i+b].setNear();  
        if(i+a <= numFlorets) florets[i+a].setNear(); 
      }
    }
  }
}